bBrowser:FormatColumns()

Zweck

Formatiert mehrere Datenspalten im Browser.

Klasse

bBrowser

Typ

Methode

Syntax

<oBrowser>:FormatColumns(auFormat) Æ lSuccess

Argumente

auFormat

1- oder 2-dimensionales Array, das für die Datenspalten eine oder mehrere Formatierungen enthält.

Datentyp:

Array

Rückgabewert

lSuccess

Logischer Wert der definiert, ob die Datenspalten formatiert werden konnten.

TRUE	Die Datenspalten konnten formatiert werden.

FALSE

Die Datenspalten konnten nicht formatiert werden.

Datentyp:

Logic

Beschreibung

bBrowser:FormatColumns() formatiert mehrere Datenspalten im Browser.

Für das Argument <auFormat> werden die folgenden Array-Arten unterstützt:

•	1-dimensionales Array Für jede Datenspalte muss ein Element im Array existieren, das die Spaltenbezeichnung als String enthält.

•

2-dimensionales Array:
Jedes Sub-Array besteht aus 2 Elementen. Das erste Element enthält den Namen der Datenspalte als String oder Symbol. Das zweite Element kann entweder die Spaltenbezeichnung als String enthalten oder ein Objekt der Klasse bNameArray. Bei einem Objekt der Klasse bNameArray werden die folgenden Namen für Werte unterstützt:

•	#Alignment

•

#AutoEdit

•	#Background

•

#Caption

•	#CaptionView

•	#CaptionVisible

•

#DataView

•

#Editable

•	#FieldSpec

•

#Font

•

#Footer

•	#FooterView

•	#FooterVisible

•	#Foreground

•

#Grid

•

#Movable

•	#Resizable

•	#Selectable

•	#SuspendEmptyValues

•	#TextFormat

•	#ViewValueAs

•

#Width

Zu den einzelnen Namen werden die Werte unterstützt, die auch in den gleichnamigen Zugriffen der Klasse bDataColumn unterstützt werden.

Beispiele

In dem folgenden Beispiel werden die Spaltenbezeichnungen aller Datenspalten gesetzt.

// bArrayServer erzeugen

auStruct := {;

{"LASTNAME", "C", 20, 0},;

{"FIRSTNAME", "C", 15, 0},;

{"BIRTHDAY", "D", 8, 0};

}

oasServer := bArrayServer{auStruct}

// Browser erzeugen und anzeigen

oBrowser := bBrowser{oOwner,;

1000,;

Point{0, 0},;

Dimension{300, 250}}

oBrowser:Use(oasServer)

oBrowser:Show()

// Datenspalten formatieren

acCaption := {"Nachname", "Vorname", "Geburtstag"}

oBrowser:FormatColumns(acCaption)

In dem folgenden Beispiel werden die Spaltenbezeichnungen für die 2 Datenspalten LASTNAME und FIRSTNAME gesetzt.

// bArrayServer erzeugen

auStruct := {;

{"ID", "N", 5, 0},;

{"LASTNAME", "C", 20, 0},;

{"FIRSTNAME", "C", 15, 0},;

{"BIRTHDAY", "D", 8, 0};

}

oasServer := bArrayServer{auStruct}

// Browser erzeugen und anzeigen

oBrowser := bBrowser{oOwner,;

1000,;

Point{0, 0},;

Dimension{300, 250}}

oBrowser:Use(oasServer)

oBrowser:Show()

// Datenspalten formatieren

auCaption := {;

{#FIRSTNAME, "Vorname"},;

{#LASTNAME, "Nachname"};

}

oBrowser:FormatColumns(auCaption)

In dem folgenden Beispiel werden mit der Klasse bNameArray mehrere Formatierungen an einzelnen Datenspalten vorgenommen.

// bArrayServer erzeugen

auStruct := {;

{"ID", "N", 5, 0},;

{"LASTNAME", "C", 20, 0},;

{"FIRSTNAME", "C", 15, 0},;

{"BIRTHDAY", "D", 8, 0};

}

oasServer := bArrayServer{auStruct}

// Browser erzeugen und anzeigen

oBrowser := bBrowser{oOwner,;

1000,;

Point{0, 0},;

Dimension{300, 250}}

oBrowser:Use(oasServer)

oBrowser:Show()

// Datenspalten formatieren

auFormat := {}

onaColumn := bNameArray{}

onaColumn:Add(#Caption, "Nachname")

onaColumn:Add(#Width, 100)

onaColumn:Add(#AutoEdit, #Sensitive)

AADD(auFormat, {#LASTNAME, onaColumn})

onaColumn := bNameArray{}

onaColumn:Add(#Caption, "Vorname")

onaColumn:Add(#Width, 80)

onaColumn:Add(#AutoEdit, #Sensitive)

AADD(auFormat, {#FIRSTNAME, onaColumn})

onaColumn := bNameArray{}

onaColumn:Add(#Width, 40)

onaColumn:Add(#Editable, FALSE)

onaColumn:Add(#Grid, bGrid{ BGRID_CONVEX})

AADD(auFormat, {#ID, onaColumn})

oBrowser:FormatColumns(auFormat)

Siehe auch

bBrowser:Use()

Page url: http://www.YOURSERVER.com/index.html?bbrowser_formatcolumns.htm